// QuakeWorld Teamplay Config

// Set _multipleTimers to zero for the old "ctf" style timer.  There will be 
// only one timer that you can control and you simply press the button
// corresponding to the item you want to display.

// _multipleTimers "1" will give you a seperate timer for each item.  In this
// case your item buttons switch your timer and the additional "displayTime"
// bind will display whichever timer you have selected. 

// Note that in addition to the standard 0-59 time display there are two other
// "times" which allow you to ask for an item time or say an item is "soon".

    ________________________________________________________
// /SET YOUR SET NICK TO A 4 LETTER ABBREVATION OF YOUR NAME\
   ŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻŻ

set _multipleTimers "0"
set nick ""

tp_pickup    quad pent ring ra ya ga mh lg rl gl sng pack runes
tp_point     quad pent ring ra ya ga mh lg rl gl sng pack runes players rockets

alias f_newmap "_setupLocations" // add this to your f_newmap alias if you have other stuff

// Configure binds:

bind n          "_cancel" 						//disregard last teambind
bind 3          "_coming" 						//coming thru location
bind "f1"       "_enemyLocation1" 					//map dependant enemy location
bind "f2"       "_enemyLocation2" 					//map dependant enemy location
bind "f3"       "_enemyLocation3" 					//map dependant enemy location
bind "f4"       "_enemyLocation4" 					//map dependant enemy location
bind "f5"       "_enemyLocation5" 					//map dependant enemy location
bind 2          "_epowerups;_epowerups" 				//enemy quad 
bind c		"_help" 						//help @ your location
bind x          "_lost" 						//lost @ your location
bind z          "shownick;_point;_point" 				//points at items/enemies (mess around with to get used to but is very important)
bind m          "_packs" 						//tell someone to take your pack
bind h          "_qdead;_qdead" 					//quad dead
bind b		"_safe" 						//safe @ your location
bind g          "_slipped" 						//enemy slipped past you (Usually good for when enemy goes thur a tele)
bind v          "_status" 						//your vital stats ie: armor/health and if you have rl or lg or both(rlg) and ammo
bind 6          "_sync" 						//sync attack at location
bind y          "_switch" 						//switch positions with teammate
bind t          "_take" 						//waiting @ your location or item soon or tell teammate to take item ie: ra/mega/rl/etc (mess around with to get a feel)
bind ctrl       "_took;if $need != $tp_name_nothing then _need" 	//took something/need something (mess around with to get a feel)
bind 1          "_weakrl" 						//weak enemy rl @ location
bind j	        "_enemylg" 						//enemy has lg
bind 4          "_getquad;_getquad"                      		//get quad
bind 5          "_getpent;_getpent"                      		//get pent
bind mouse4     "_mapStatus" 						//ask your teammates what their status is
bind F6         "_timerDisplay" 					//only needed if _multipleTimers == 1 (advanced read above...only used as a replacement for get quad and get pent msgs)


//New Binds
alias _enemylg  "say_team $\$nick $_enemylgBubble $tp_name_enemy {has} $tp_name_lg"

// Configure per map enemy locations
// Available options: _era, _ega, _eya, _elg, _erl, _egl, _esng, _elifts, _eratun, _ewindow, _etele, _esecret, _elarge, _eramega, _ehigh, _emega, _equad

alias _setupDM3         "alias _mapStatus _mapStatusRAYA; alias _enemyLocation1 _era;   alias _enemyLocation2 _eratun; alias _enemyLocation3 _esng;    alias _enemyLocation4 _eya;     alias _enemyLocation5 _elifts"
alias _setupDM2         "alias _mapStatus _mapStatusTele; alias _enemyLocation1 _ehigh; alias _enemyLocation2 _elarge; alias _enemyLocation3 _eramega; alias _enemyLocation4 _esecret; alias _enemyLocation5 _etele"
alias _setupE1M2        "alias _mapStatus _mapStatusYAMH; alias _enemyLocation1 _emega; alias _enemyLocation2 _equad;  alias _enemyLocation3 _egl;     alias _enemyLocation4 _eya;     alias _enemyLocation5 _erl"
alias _setupDefaults    "alias _mapStatus _mapStatusRAYA; alias _enemyLocation1 _era;   alias _enemyLocation2 _eya;    alias _enemyLocation3 _equad;   alias _enemyLocation4 _emega;   alias _enemyLocation5 _etele"

// Configure initial times (optional):

set _time     "56"  // if _multipleTimers == 0
set _quadTime "56"  // 3-5 would be wise if your clock counts up
set _pentTime "61"  // soon
set _rlTime   "30"

// Configure color display


// No need to change below 

set _cancelBubble "  "
set _comingBubble "  "
set _droppedPackBubble "$R$R"
set _ePowerupsBubble "$R$R"
set _enemyLocationBubble "  "
set _helpBubble "$Y$Y"
set _lostBubble "$R$R"
set _needBubble "  "
set _pointGBubble "  "
set _pointRBubble "  "
set _pointYBubble "  "
set _powerupNeedBubble "  "
set _qDeadBubble "$G$G"
set _safeBubble "$G$G"
set _slippedBubble "  "
set _soonBubble "  "
set _statusBubble "  "
set _switchBubble "$Y$Y"
set _syncBubble "  "
set _takeBubble "  "
set _takePackBubble "  "
set _trickBubble "  "
set _timeBubble "$x04$x04"
set _tookBubble "$B$B"
set _tookPowerupBubble "$G$G"
set _waitBubble "  "
set _weakrlBubble "$R$R"
set _mapStatusBubble "  "
set _enemylgBubble "$R$R"

tp_name_rl           "{&cf0frl&cfff}"
tp_name_lg           "{&cf0flg&cfff}"
set _rlg             "{&cf0frlg&cfff}"

//set _q "{&c03fq&cfff}"  // {q}
//set _p "{&ce00p&cfff}"  // {p}
//set _r "{&cff0r&cfff}"  // {r}
set _q $x9e                                           // {q}
set _p $x9d                                           // {p}
set _r $x9f                                           // {r}

//tp_name_armortype_ga "{&c0b0g&cfff}" // g
//tp_name_armortype_ya "{&cff0y&cfff}" // y
//tp_name_armortype_ra "{&ce00r&cfff}" // r
tp_name_armortype_ga "{$x01}"                         // g
tp_name_armortype_ya "{$x03}"                         // y
tp_name_armortype_ra "{$x05}"                         // r

tp_name_ga           "{&c0b0ga&cfff}"       // ga
tp_name_ya           "{&cff0ya&cfff}"       // ya
tp_name_ra           "{&ce00ra&cfff}"       // ra
tp_name_mh           "{&c03Fmega&cfff}"     // mega
tp_name_enemy        "{&ce00enemy&cfff}"	// enemy
tp_name_backpack     "{&cF0Fpack&cfff}"     // pack

tp_name_quad "{&c03Fquad&cfff}"
tp_name_pent "{&ce00pent&cfff}"
tp_name_ring "{&cff0ring&cfff}"
tp_name_quaded "{&c03Fquaded&cfff}"
tp_name_pented "{&ce00pented&cfff}"
tp_name_weapon "weapon"
tp_name_rune1 "{res}"
tp_name_rune2 "{str}"
tp_name_rune3 "{hst}"
tp_name_rune4 "{rgn}"
tp_name_separator "$x20"
set _quad    "quad"
set _pent    "pent"
set _rl      "rl"
set _item    "$_quad"
set _zero    "0"

// ****** Map Status? ******

alias _mapStatusRAYA "say_team $\$nick $_mapStatusBubble status? $[$tp_name_ra/$tp_name_ya$]"
alias _mapStatusTele "say_team $\$nick $_mapStatusBubble status? $[{tele}$]"
alias _mapStatusYAMH "say_team $\$nick $_mapStatusBubble status? $[$tp_name_ya/$tp_name_mh$]"

// ****** Timer ******

alias _timerSetEcho     "set _displayTime $_time; if $_time == 60 then set _displayTime ?? else if $_time == 61 then set _displayTime soon"
alias _timerEchoTime    "if $_multipleTimers == 0 then echo time -> $_displayTime else echo $_item time -> $_displayTime"

alias _timerRL          "set _item $_rl; if $_multipleTimers == 0 then _timerDisplay else _timerSelected"
alias _timerPent        "set _item $_pent; if $_multipleTimers == 0 then _timerDisplay else _timerSelected"
alias _timerQuad        "set _item $_quad; if $_multipleTimers == 0 then _timerDisplay else _timerSelected"  

alias _timerInc         "if $_multipleTimers == 0 then _timerIncSingle else _timerIncMultiple"
alias _timerDec         "if $_multipleTimers == 0 then _timerDecMultiple else _timerDecMultiple"
alias _timerIncSingle   "inc _time; if $_time > 61 then inc _time -62; _timerSetEcho; _timerEchoTime; _timerPad"
alias _timerDecSingle   "inc _time -1; if $_time < 0 then inc _time 62; _timerSetEcho; _timerEchoTime; _timerPad"
alias _timerIncMultiple "inc _time; if $_time > 61 then inc _time -62; _timerSetEcho; _timerEchoTime; _timeSet; _timerPad"
alias _timerDecMultiple "inc _time -1; if $_time < 0 then inc _time 62; _timerSetEcho; _timerEchoTime; _timeSet; _timerPad"
alias _timerDisplay     "if $_time == 60 then _timerUnknown else if $_time == 61 then _timerSoon else _timerItemTime"
alias _timerSelected    "_timerSet; _timerSetEcho; _timerEchoTime"
alias _timerSet         "if $_item == $_quad then set _time $_quadTime else if $_item == $_pent then set _time $_pentTime else set _time $_rlTime"
alias _timeSet          "if $_item == $_quad then set _quadTime $_time else if $_item == $_pent then set _pentTime $_time else set _rlTime $_time"
alias _timerPad         "if $_time < 10 then set _time $_zero$_time
alias _timerPadD        "if $_displayTime < 10 then set _displayTime $_zero$_displayTime

alias _timerSoon        "if $_item == $_quad then _saySoonQ else if $_item == $_pent then _saySoonP else _sayItemSoon"
alias _sayItemSoon      "say_team $\$nick $_soonBubble {$_item} soon"
alias _saySoonQ         "say_team $\$nick $_soonBubble $tp_name_quad soon"
alias _saySoonP         "say_team $\$nick $_soonBubble $tp_name_pent soon"

alias _timerUnknown     "if $_item == $_quad then _sayUnknownQ else if $_item == $_pent then _sayUnknownP else _sayItemUnknown"
alias _sayItemUnknown   "say_team $\$nick $_timeBubble {$_item} time?"
alias _sayUnknownQ      "say_team $\$nick $_timeBubble $tp_name_quad time?"
alias _sayUnknownP      "say_team $\$nick $_timeBubble $tp_name_pent time?"

alias _timerItemTime    "if $_item == $_quad then _sayTimeQ else if $_item == $_pent then _sayTimeP else _timerItemCheck"
alias _timerItemCheck   "if $_item == $_rl then _timerSetupRLTime"
alias _timerSetupRLTime "set _displayTime $_time; _timerOtherRLTime; _timerPadD; _timerChooseRL" 
alias _timerChooseRL    "if $_displayTime > $_time then _sayTimeRL1 else _sayTimeRL2"
alias _timerOtherRLTime "if $_time > 29 then inc _displayTime -30 else inc _displayTime 30"

alias _sayTimeRL1       "say_team $\$nick $_timeBubble $tp_name_rl at $[$_time/$_displayTime$]"
alias _sayTimeRL2       "say_team $\$nick $_timeBubble $tp_name_rl at $[$_displayTime/$_time$]"
alias _sayTimeQ         "say_team $\$nick $_timeBubble $tp_name_quad at $[$_time$]"
alias _sayTimeP         "say_team $\$nick $_timeBubble $tp_name_pent at $[$_time$]"

// ****** Status ******

alias _status           "if $health < 1 then _lost else _statusPowerups1"

alias _statusPowerups1  "if $tp_name_quad isin $powerups then _statusPowerupsQ else _statusPowerups2"
alias _statusPowerups2  "if $tp_name_pent isin $powerups then _statusPowerupsP else _statusPowerups3"
alias _statusPowerups3  "if $tp_name_ring isin $powerups then _statusNotDeadR else _statusNotDead"

alias _statusPowerupsQ  "if $tp_name_pent isin $powerups then _statusPowerupsQP else _statusPowerupsQR"
alias _statusPowerupsQR "if $tp_name_ring isin $powerups then _statusNotDeadQR else _statusNotDeadQ"
alias _statusPowerupsP  "if $tp_name_ring isin $powerups then _statusNotDeadPR else _statusNotDeadP"
alias _statusPowerupsQP "if $tp_name_ring isin $powerups then _statusNotDeadQPR else _statusNotDeadQP"

alias _statusNotDead    "if $bestweapon == $tp_name_sg then _statusAmmo else _statusWeapons"
alias _statusAmmo       "if $rockets > 0 then _msgStatusNoWeaponRockets else _msgStatusNoWeapon"
alias _statusWeapons    "if $tp_name_rl isin $weapons then _statusRL else _statusNoRL"
alias _statusRL         "if $tp_name_lg isin $weapons then _msgStatusRLG else _msgStatusWeapon"
alias _statusNoRL       "if $tp_name_lg isin $weapons then _msgStatusWeapon else _statusNoLG"
alias _statusNoLG       "if $tp_name_gl isin $weapons then _msgStatusWeapon else _msgStatusWWeaponRockets"

alias _statusNotDeadQ   "if $bestweapon == $tp_name_sg then _statusAmmoQ else _statusWeaponsQ"
alias _statusAmmoQ      "if $rockets > 0 then _msgStatusNoWeaponRocketsQ else _msgStatusNoWeaponQ"
alias _statusWeaponsQ   "if $tp_name_rl isin $weapons then _statusRLQ else _statusNoRLQ"
alias _statusRLQ        "if $tp_name_lg isin $weapons then _msgStatusRLGQ else _msgStatusWeaponQ"
alias _statusNoRLQ      "if $tp_name_lg isin $weapons then _msgStatusWeaponQ else _statusNoLGQ"
alias _statusNoLGQ      "if $tp_name_gl isin $weapons then _msgStatusWeaponQ else _msgStatusWWeaponRocketsQ"

alias _statusNotDeadQP  "if $bestweapon == $tp_name_sg then _statusAmmoQP else _statusWeaponsQP"
alias _statusAmmoQP     "if $rockets > 0 then _msgStatusNoWeaponRocketsQP else _msgStatusNoWeaponQP"
alias _statusWeaponsQP  "if $tp_name_rl isin $weapons then _statusRLQP else _statusNoRLQP"
alias _statusRLQP       "if $tp_name_lg isin $weapons then _msgStatusRLGQP else _msgStatusWeaponQP"
alias _statusNoRLQP     "if $tp_name_lg isin $weapons then _msgStatusWeaponQP else _statusNoLGQP"
alias _statusNoLGQP     "if $tp_name_gl isin $weapons then _msgStatusWeaponQP else _msgStatusWWeaponRocketsQP"

alias _statusNotDeadQR  "if $bestweapon == $tp_name_sg then _statusAmmoQR else _statusWeaponsQR"
alias _statusAmmoQR     "if $rockets > 0 then _msgStatusNoWeaponRocketsQR else _msgStatusNoWeaponQR"
alias _statusWeaponsQR  "if $tp_name_rl isin $weapons then _statusRLQR else _statusNoRLQR"
alias _statusRLQR       "if $tp_name_lg isin $weapons then _msgStatusRLGQR else _msgStatusWeaponQR"
alias _statusNoRLQR     "if $tp_name_lg isin $weapons then _msgStatusWeaponQR else _statusNoLGQR"
alias _statusNoLGQR     "if $tp_name_gl isin $weapons then _msgStatusWeaponQR else _msgStatusWWeaponRocketsQR"

alias _statusNotDeadP   "if $bestweapon == $tp_name_sg then _statusAmmoP else _statusWeaponsP"
alias _statusAmmoP      "if $rockets > 0 then _msgStatusNoWeaponRocketsP else _msgStatusNoWeaponP"
alias _statusWeaponsP   "if $tp_name_rl isin $weapons then _statusRLP else _statusNoRLP"
alias _statusRLP        "if $tp_name_lg isin $weapons then _msgStatusRLGP else _msgStatusWeaponP"
alias _statusNoRLP      "if $tp_name_lg isin $weapons then _msgStatusWeaponP else _statusNoLGP"
alias _statusNoLGP      "if $tp_name_gl isin $weapons then _msgStatusWeaponP else _msgStatusWWeaponRocketsP"

alias _statusNotDeadPR  "if $bestweapon == $tp_name_sg then _statusAmmoPR else _statusWeaponsPR"
alias _statusAmmoPR     "if $rockets > 0 then _msgStatusNoWeaponRocketsPR else _msgStatusNoWeaponPR"
alias _statusWeaponsPR  "if $tp_name_rl isin $weapons then _statusRLPR else _statusNoRLPR"
alias _statusRLPR       "if $tp_name_lg isin $weapons then _msgStatusRLGPR else _msgStatusWeaponPR"
alias _statusNoRLPR     "if $tp_name_lg isin $weapons then _msgStatusWeaponPR else _statusNoLGPR"
alias _statusNoLGPR     "if $tp_name_gl isin $weapons then _msgStatusWeaponPR else _msgStatusWWeaponRocketsPR"

alias _statusNotDeadR   "if $bestweapon == $tp_name_sg then _statusAmmoR else _statusWeaponsR"
alias _statusAmmoR      "if $rockets > 0 then _msgStatusNoWeaponRocketsR else _msgStatusNoWeaponR"
alias _statusWeaponsR   "if $tp_name_rl isin $weapons then _statusRLR else _statusNoRLR"
alias _statusRLR        "if $tp_name_lg isin $weapons then _msgStatusRLGR else _msgStatusWeaponR"
alias _statusNoRLR      "if $tp_name_lg isin $weapons then _msgStatusWeaponR else _statusNoLGR"
alias _statusNoLGR      "if $tp_name_gl isin $weapons then _msgStatusWeaponR else _msgStatusWWeaponRocketsR"

alias _statusNotDeadQPR "if $bestweapon == $tp_name_sg then _statusAmmoQPR else _statusWeaponsQPR"
alias _statusAmmoQPR    "if $rockets > 0 then _msgStatusNoWeaponRocketsQPR else _msgStatusNoWeaponQPR"
alias _statusWeaponsQPR "if $tp_name_rl isin $weapons then _statusRLQPR else _statusNoRLQPR"
alias _statusRLQPR      "if $tp_name_lg isin $weapons then _msgStatusRLGQPR else _msgStatusWeaponQPR"
alias _statusNoRLQPR    "if $tp_name_lg isin $weapons then _msgStatusWeaponQPR else _statusNoLGQPR"
alias _statusNoLGQPR    "if $tp_name_gl isin $weapons then _msgStatusWeaponQPR else _msgStatusWWeaponRocketsQPR"

alias _msgStatusNoWeapon           "say_team $\$nick $_statusBubble %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponQ          "say_team $\$nick $_statusBubble $_q %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponP          "say_team $\$nick $_statusBubble $_p %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponR          "say_team $\$nick $_statusBubble $_r %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponQP         "say_team $\$nick $_statusBubble $_q$_p %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponQR         "say_team $\$nick $_statusBubble $_q$_r %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponPR         "say_team $\$nick $_statusBubble $_p$_r %a%A/%h $[{%l}$]"
alias _msgStatusNoWeaponQPR        "say_team $\$nick $_statusBubble $_q$_p$_r %a%A/%h $[{%l}$]"

alias _msgStatusNoWeaponRockets    "say_team $\$nick $_statusBubble %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsQ   "say_team $\$nick $_statusBubble $_q %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsP   "say_team $\$nick $_statusBubble $_p %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsR   "say_team $\$nick $_statusBubble $_r %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsQP  "say_team $\$nick $_statusBubble $_q$_p %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsQR  "say_team $\$nick $_statusBubble $_q$_r %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsPR  "say_team $\$nick $_statusBubble $_p$_r %a%A/%h ({$rockets}) $[{%l}$]"
alias _msgStatusNoWeaponRocketsQPR "say_team $\$nick $_statusBubble $_q$_p$_r %a%A/%h ({$rockets}) $[{%l}$]"

alias _msgStatusWWeaponRockets     "say_team $\$nick $_statusBubble %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsQ    "say_team $\$nick $_statusBubble $_q %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsP    "say_team $\$nick $_statusBubble $_p %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsR    "say_team $\$nick $_statusBubble $_r %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsQP   "say_team $\$nick $_statusBubble $_q$_p %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsQR   "say_team $\$nick $_statusBubble $_q$_r %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsPR   "say_team $\$nick $_statusBubble $_p$_r %a%A/%h$.%b ({$rockets}) $[{%l}$]"
alias _msgStatusWWeaponRocketsQPR  "say_team $\$nick $_statusBubble $_q$_p$_r %a%A/%h$.%b ({$rockets}) $[{%l}$]"

alias _msgStatusWeapon             "say_team $\$nick $_statusBubble %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponQ            "say_team $\$nick $_statusBubble $_q %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponP            "say_team $\$nick $_statusBubble $_p %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponR            "say_team $\$nick $_statusBubble $_r %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponQP           "say_team $\$nick $_statusBubble $_q$_p %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponQR           "say_team $\$nick $_statusBubble $_q$_r %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponPR           "say_team $\$nick $_statusBubble $_p$_r %a%A/%h$.%b $[{%l}$]"
alias _msgStatusWeaponQPR          "say_team $\$nick $_statusBubble $_q$_p$_r %a%A/%h$.%b $[{%l}$]"

alias _msgStatusRLG                "say_team $\$nick $_statusBubble %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGQ               "say_team $\$nick $_statusBubble $_q %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGP               "say_team $\$nick $_statusBubble $_p %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGR               "say_team $\$nick $_statusBubble $_r %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGQP              "say_team $\$nick $_statusBubble $_q$_p %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGQR              "say_team $\$nick $_statusBubble $_q$_r %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGPR              "say_team $\$nick $_statusBubble $_p$_r %a%A/%h$.$_rlg:$rockets $[{%l}$]"
alias _msgStatusRLGQPR             "say_team $\$nick $_statusBubble $_q$_p$_r %a%A/%h$.$_rlg:$rockets $[{%l}$]"

// Need - not allowed to complain about armor\health if you dont have a weapon or powerup

alias _need             "if $need != $tp_name_nothing then _needSanityCheck"
alias _needSanityCheck  "if $tp_name_quad isin $powerups then _msgNeed else if $tp_name_pent isin $powerups then _msgNeed else if $tp_name_ring isin $powerups then _msgNeed else _needSanityCheck2"
alias _needSanityCheck2 "if $bestweapon == $tp_name_sg then _msgNeedWeapon else _msgNeed"
alias _msgNeed          "say_team $\$nick $_needBubble need %u"
alias _msgNeedWeapon    "say_team $\$nick $_needBubble need weapon"

// Lost - Press before respawning for pack drops to work (if you respawn use _packs)

alias _lost             "if $tp_name_rl == $weapon then _msgLostPack else if $tp_name_lg == $weapon then _msgLostPack else _msgLost"
alias _msgLost          "say_team $\$nick $_lostBubble lost $[{%d}$] %E"
alias _msgLostPack      "say_team $\$nick $_droppedPackBubble lost $weapon $[{%d}$] %E"

// Packs

alias _packs            "if $tp_name_rl isin $weapons then _packsHasRL else _msgPacksDropped"
alias _packsHasRL       "if $health > 0 then _msgTakePack else _msgLostPack"
alias _msgTakePack      "say_team $\$nick $_takePackBubble take my $tp_name_backpack $[{%l}$]"
alias _msgPacksDropped  "say_team $\$nick $_droppedPackBubble dropped pack $[{%d}$] %E"

// Took

alias _took             "if $took == $tp_name_nothing else if $took == $tp_name_quad then _tookPowerup else if $took == $tp_name_pent then _tookPowerup else if $took = $tp_name_ring then _tookPowerup else _msgTookItem"
alias _tookPowerup      "_msgTookPowerup; _msgTookPowerup; if $need != $tp_name_nothing then _tookPowerupNeed"
alias _tookPowerupNeed  "if $took == $tp_name_quad then _tookPowerupNeedQ else if $took == $tp_name_pent then _tookPowerupNeedP"
alias _tookPowerupNeedQ "say_team $\$nick $_powerupNeedBubble {&cff0}{need $need}"
alias _tookPowerupNeedP "if weapon isin $need then _msgNeedRL"
alias _msgTookPowerup   "say_team $\$nick $_tookPowerupBubble {&c0b0}{team}{&cfff} $took"
alias _msgNeedRL        "say_team $\$nick $_powerupNeedBubble {&cff0}{need rl}"
alias _msgTookItem      "say_team $\$nick $_tookBubble took $took $[{%Y}$]"

// Point

alias _point            "if $qt$point$qt = $qt$tp_name_nothing$qt then else if $ledpoint = $tp_name_status_red then _pointEPowerup else if $ledpoint = $tp_name_status_yellow then _msgPointY else if $ledpoint = $tp_name_status_green then else _msgPointG"

alias _pointEPowerup    "if $qt$tp_name_eyes$qt isin $qt$point$qt then _msgPointR else _pointEPowerup2"
alias _pointEPowerup2   "if $qt$tp_name_quaded$qt isin $qt$point$qt then _pointEQ else _pointEPowerup3"
alias _pointEPowerup3   "if $qt$tp_name_pented$qt isin $qt$point$qt then _msgPointP else _msgPointR"
alias _pointEQ          "if $qt$tp_name_pented$qt isin $qt$point$qt then _msgPointQP else _msgPointQ"

alias _msgPointQP       "say_team $\$nick $_pointRBubble $tp_name_quad $tp_name_pented {$x1f}{$x1d}{$x1f}{$x1e}{$x09} at $[{%y}$] %E"
alias _msgPointQ        "say_team $\$nick $_pointRBubble $tp_name_quaded {$x1f}{$x1d}{$x1f}{$x1e}{$x09} at $[{%y}$] %E"
alias _msgPointP        "say_team $\$nick $_pointRBubble $tp_name_pented {$x1f}{$x1d}{$x1f}{$x1e}{$x09} at $[{%y}$] %E"
alias _msgPointG        "say_team $\$nick $_pointGBubble %x at $[{%y}$]"
alias _msgPointY        "say_team $\$nick $_pointYBubble %x up" 
alias _msgPointR        "say_team $\$nick $_pointRBubble %x $tp_name_rl at $[{%y}$] %E"

// Take  

alias _take                    "if $health < 1 then _lost else _take_try"
alias _take_ga                 "if $armor < $tp_need_ga then _wait else _soon"
alias _take_lg                 "if $bestweapon isin $tp_name_lg then _soon else _take_point_it"
alias _take_point              "if $ledpoint = $tp_name_status_green then _youtake else _take_point_1"
alias _take_point_1            "if $qt$point$qt != $qtrl$qt then _take_point_2 else if $qtrl$qt isin $location then _point else _take_point_2"
alias _take_point_2            "if $qt$point$qt != $qtlg$qt then _take_point_3 else if $qtlg$qt isin $location then _point else _take_point_3"
alias _take_point_3            "if $qt$point$qt != $qtra$qt then _take_point_4 else if $qtra$qt isin $location then _point else _take_point_4"
alias _take_point_4            "if $qt$point$qt != $qtya$qt then _take_point_5 else if $qtya$qt isin $location then _point else _take_point_5"
alias _take_point_5            "if $qt$point$qt != $qtga$qt then _take_try_ra else if $qtga$gt isin $location then _point else _take_try_ra"
alias _take_point_c            "if $qt$point$qt != $qt$tp_name_cells$qt then _wait else _point"
alias _take_point_it           "if $ledpoint = $tp_name_status_blue then _take_point_c else _wait"
alias _take_ra                 "if $armor < $tp_need_ra then _wait else _soon"
alias _take_rl                 "if $bestweapon isin $tp_name_rl then _soon else _wait"
alias _take_try                "if $qt$point$qt != $tp_name_nothing then _take_point else _take_try_ra"
alias _take_try_dm2            "if $mapname != $qtdm2$qt then _take_try_ya else if $qtsecret$qt = $qt$location$qt then _take_ra else _take_try_ya"
alias _take_try_ga             "if $qtga$qt isin $location then _take_ga else _take_try_rl"
alias _take_try_lg             "if $qtlg$qt isin $location then _take_lg else _take_point_it"
alias _take_try_mega           "if $qtmega$qt isin $location then _wait else _take_try_ga"
alias _take_try_ra             "if $qtra$qt isin $location then _take_ra else _take_try_dm2"
alias _take_try_rl             "if $qtrl$qt isin $location then _take_rl else _take_try_lg"
alias _take_try_ya             "if $qtya$qt isin $location then _take_ya else _take_try_mega"
alias _take_ya                 "if $armor < $tp_need_ra then _wait else _soon"
alias _youtake                 "if $ledpoint == $tp_name_status_green _msgTakeNick else _msgTake
alias _msgTakeNick             "say_team $\$nick $_takeBubble %x take $[{%l}$]"
alias _msgTake                 "say_team $\$nick $_takeBubble you take $[{%l}$]"

// Enemy Locations

alias _setupLocations   "if $mapname == $qtdm3$qt then _setupDM3 else if $mapname == $qtdm2$qt then _setupDM2 else if $mapname == $qte1m2$qt then _setupE1M2 else _setupDefaults"

alias _emega            "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{mega}$]"
alias _esng             "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{sng}$]"
alias _etele            "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{tele}$]"
alias _eramega          "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{ra-mega}$]"
alias _erl              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{rl}$]"
alias _egl              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{gl}$]"
alias _elg              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{lg}$]"
alias _elifts           "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{lifts}$]"
alias _era              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{ra}$]"
alias _ega              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{ga}$]"
alias _equad            "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{quad}$]"
alias _ewindow          "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{window}$]"
alias _eya              "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{ya}$]"
alias _esecret          "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{secret}$]"
alias _ehigh            "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{high}$]"
alias _elarge           "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{large}$]"
alias _eratun           "say_team $\$nick $_enemyLocationBubble $tp_name_enemy at $[{ra-tunnel}$]"

// Slipped 

alias _slipped "if $mapname = $qtdm2$qt then _slipdm2 else if $mapname = $qtdm3 then _slipdm3 else msgSlipped"
alias _slipdm2 "if $location = $qtra-mega$qt then _elarge else if $location = $qttele$qt then _ehigh else if $location = $qtlower$qt then _esecret else if $location = $qtlower-lift$qt then _esecret else if $location = $qtlower-button$qt then _elarge else msgSlipped"
alias _slipdm3 "if $location = $qtya$qt then _ewindow else if $location = $qtya-box$qt then _ewindow else if $location = $qtya-ammo$qt then _ewindow else if $location = $qtya-ssg$qt then _ewindow else _slipdm3_2"
alias _slipdm3_2 "if $location = $qtring$qt then _esng else if $location = $qtra-entrance$qt then _esng else if $location = $qtlifts-below$qt then _esng else if $location = $qtring-lifts$qt then _esng else _slipdm3_3"
alias _slipdm3_3 "if $location = $qtrl$qt then _eya else if $location = $qtrl-entrance$qt then _eya else if $location = $qtlow-bridge$qt then _eya else _slipdm3_4"
alias _slipdm3_4 "if $location = $qtpent$qt then _elifts else if $location = $qtpent-water$qt then _elifts else if $location = $qtpent-mega$qt then _elifts else if $location = $qtlifts$qt then _elifts else msgSlipped"

alias msgSlipped        "say_team $\$nick $_slippedBubble $tp_name_enemy slipped $[{%l}$]"

// Trick

alias _trick "if $mapname = $qtdm2$qt then _trickdm2 else if $mapname = $qtdm3$qt then _trickdm3 else msgTrick"  
alias _trickdm2 "if $location = $qtquad-below$qt then msgShortcut else if $location = $qtsecret$qt then msgSecret else if $location = $qtwater$qt then msgSecret else if $location = $qtlower-button$qt then msgRaMega else if $location = $qttele$qt then msgTele else msgTrick"
alias _trickdm3 "if $location = $qtwater$qt then msgDischargeW else if $location = $qtwater-ammo$qt then msgDischargeW else if $location = $qtwater-gl$qt then msgDischargeW else if $location = $qtwater-lg$qt then msgDischargeW else if $location = $qtwater-tunnel$qt then msgDischargeP else if $location = $qtpent-water$qt then msgDischargeP else msgTrick"

alias msgShortcut       "say_team $\$nick $_trickBubble shortcut $[$tp_name_quad$]"
alias msgSecret         "say_team $\$nick $_trickBubble open $[{secret}$]"
alias msgRaMega         "say_team $\$nick $_trickBubble open $[{ra-mega}$]"
alias msgDischargeW     "say_team $\$nick $_trickBubble discharge $[{water}$]"
alias msgDischargeP     "say_team $\$nick $_trickBubble discharge $[{penta}$]"
alias msgTrick          "say_team $\$nick $_trickBubble trick $[{%l}$]"
alias msgTele           "say_team $\$nick $_trickBubble open $[{tele-ya}$]"

// The one liners..

alias _cancel           "say_team $\$nick $_cancelBubble cancel/hell no/FUCK YOU"
alias _coming 	        "say_team $\$nick $_comingBubble coming $[{%l}$]"
alias _epowerups        "say_team $\$nick $_ePowerupsBubble $tp_name_enemy %q"
alias _help             "say_team $\$nick $_helpBubble help $[{%l}$] %E" 
alias _qdead            "say_team $\$nick $_qDeadBubble killed $tp_name_quad"
alias _safe             "say_team $\$nick $_safeBubble safe $[{%l}$]"
alias _soon             "say_team $\$nick $_soonBubble soon $[{%l}$]"
alias _switch 	        "say_team $\$nick $_switchBubble switch $[{%l}$]"
alias _sync             "say_team $\$nick $_syncBubble sync $[{%l}$] %E"
alias _wait             "say_team $\$nick $_waitBubble waiting at $[{%l}$]"
alias _weakrl           "say_team $\$nick $_weakrlBubble $tp_name_enemy $tp_name_rl weak $[{%d}$] %E"
alias _getpent          "say_team $\$nick get $tp_name_pent"
alias _getquad          "say_team $\$nick get $tp_name_quad"